// Next available MSG number is    17 
// MODULE_ID DDGRIPS_DCL_
/* Next available MSG number is  18 */

//----------------------------------------------------------------------------
//
//     ddgrips.dcl
//
//     Copyright (C) 1992, 1994 by Autodesk, Inc.
//
//     Permission to use, copy, modify, and distribute this software
//     for any purpose and without fee is hereby granted, provided
//     that the above copyright notice appears in all copies and
//     that both that copyright notice and the limited warranty and
//     restricted rights notice below appear in all supporting
//     documentation.
//
//     AUTODESK PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
//     AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
//     MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK, INC.
//     DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
//     UNINTERRUPTED OR ERROR FREE.
//
//     Use, duplication, or disclosure by the U.S. Government is subject to
//     restrictions set forth in FAR 52.227-19 (Commercial Computer
//     Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii)
//     (Rights in Technical Data and Computer Software), as applicable.
//
//.
//    
//----------------------------------------------------------------------------


//dcl_settings : default_dcl_settings { audit_level = 3; }


ddgrips : dialog {
    label = "Grips";
    : boxed_column {
        label = "Select Settings";
        : toggle {
            label = "Enable Grips";
            key = "grips";
            mnemonic = "E";
            fixed_width = true;
        }
        : toggle {
            label = "Enable Grips Within Blocks";
            key = "gripblock";
            mnemonic = "B";
            fixed_width = true;
        }
    }
    : boxed_column {
         label = "Grip Colors";
         : row {
             : column {
                 : button {
                     label = "Unselected...";
                     key = "cool_color";
                     mnemonic = "U";
                 }
                 : button {
                     label = "Selected...";
                     key = "hot_color";
                     mnemonic = "S";
                 }
             }
             : column {
                 : image {
                     key = "cool_image";
                     height = 1;
                     width = 3;
                     fixed_width = true;
                     fixed_height = true;
                 }
                 : image {
                     key = "hot_image";
                     height = 1;
                     width = 3;
                     fixed_width = true;
                     fixed_height = true;
                 }
             }
             : column {
                 : text {
                     label = "Blue";
                     key = "cool_text";
                     width = 11;
                 }
                 : text {
                     label = "Red";
                     key = "hot_text";
                     width = 11;
                 }
             }
        }
    }
    : boxed_row {
        label = "Grip Size";
        mnemonic = "G";
        spacer_0;
       : column {
            spacer_0;
            fixed_width = true;
            : text {
                label = "Min         Max";
                alignment = centered;
            }
            : slider {
                key = "grip_slider";
                min_value = 0;
                max_value = 19;
                width = 20;
                height = 1;
                small_increment = 1;
                big_increment = 1;
                fixed_width = true;
                fixed_height = true;
            }
            spacer_0;
        }
        : image {
            key = "grip_image";
            aspect_ratio = 1;
            height = 4;
            width = 7;
            color = -2;
        }
        spacer_0;
    }
    ok_cancel_help;
}



