// Next available MSG number is   256 
// MODULE_ID HPMPLOT_DCL_
//  (Test Release 0.1  12 Nov 1992)
//  (C) Hewlett-Packard Company
//  HP-GL/2 ADI 4.2 AutoCAD 386 Release 12 driver
//  Release 1.3   1 March 1993 
//  HPMPLOT.DCL 
//  Main Menu for the Merge Plotting/Rendering User Interface

mainmenu: dialog {
    label = /*HPMPLOT_DCL_1*/"HP Plotter Configuration";
    alignment = centered;
    initial_focus = /*MSG0*/"accept";
    : column {
        : text_part {
            key = /*MSG0*/"modellabel";
            label = /*HPMPLOT_DCL_2*/"Plotter Conf:";
        }
        : popup_list {
            fixed_width = true;
            key = /*MSG0*/"idmodel";
            edit_width = 60;
	    tabs = "25";
        }
    }
    : concatenation {
        : text_part {
            key = /*MSG0*/"dirlabel";
            label = /*HPMPLOT_DCL_3*/"Dir: ";
        }
        : text {
            key = /*MSG0*/"dir";
            width = 34;
        }
    }
    : row {
        fixed_width = true;
        : text {
            label = /*HPMPLOT_DCL_4*/"Configuration File:";
            key = /*MSG0*/"cfglabel";
            mnemonic = /*HPMPLOT_DCL_5*/"C";
        }
        : popup_list {
            fixed_width = true;
            key = /*MSG0*/"cfgfile";
            edit_width = 13;
        }
    }
    : row {
        : column {  // Begin Left Column
            : boxed_radio_column {
                label = /*HPMPLOT_DCL_6*/"Quality";
                key   = /*MSG0*/"qual";
                : radio_button {
                    label = /*HPMPLOT_DCL_7*/"Draft";
                    key = /*MSG0*/"draft";
                    mnemonic = /*HPMPLOT_DCL_8*/"D";
                }
                : radio_button {
                    label = /*HPMPLOT_DCL_9*/"Final";
                    key = /*MSG0*/"final";
       	            mnemonic = /*HPMPLOT_DCL_250*/"F";
                    value = "1";
                }
                : radio_button {
                    label = /*HPMPLOT_DCL_10*/"Enhanced";
                    key = /*MSG0*/"enhanced";
                    mnemonic = /*HPMPLOT_DCL_11*/"E";
                }
                : radio_button {
                    label = /*HPMPLOT_DCL_12*/"Plotter Default";
                    key = /*MSG0*/"pldefault";
                    mnemonic = /*HPMPLOT_DCL_13*/"t";
                }
            }  // End radio_column (Print Qual) //
        }  // End Left Column
        : column {  // Begin Middle Column
            : edit_box {
                label = /*HPMPLOT_DCL_14*/"Number of Copies:";
                mnemonic = /*HPMPLOT_DCL_15*/"N";
                key = /*MSG0*/"copies";
                edit_width = 2;
	        edit_limit = 2;
                fixed_width=true;
            }
            : boxed_radio_column {
                label = /*HPMPLOT_DCL_16*/"Print colors";
                key   = /*MSG0*/"color_set";
                : radio_button {
                    label = /*HPMPLOT_DCL_17*/"In color";
                    key = /*MSG0*/"pcolor";
                    mnemonic = /*HPMPLOT_DCL_18*/"c";
                }
                : radio_button {
                    label = /*HPMPLOT_DCL_19*/"Colors as gray";
                    key = /*MSG0*/"pgray";
       	            mnemonic = /*HPMPLOT_DCL_20*/"g";
                }
                : radio_button {
                    label = /*HPMPLOT_DCL_21*/"All as black";
                    key = /*MSG0*/"pblack";
                    mnemonic = /*HPMPLOT_DCL_22*/"b";
                }
	    } //end of color setting
        }
        : column {  
            // Begin Right Column
            : button {
                label = /*HPMPLOT_DCL_23*/"Pens...";
                mnemonic = /*HPMPLOT_DCL_24*/"P";
                key = /*MSG0*/"penattr";
            }
            : button {
                label = /*HPMPLOT_DCL_25*/"Annotations...";
                mnemonic = /*HPMPLOT_DCL_26*/"A";
                key = /*MSG0*/"annotate";
            }
            : button {
                label = /*HPMPLOT_DCL_27*/"Media Orientation...";
	        mnemonic = /*HPMPLOT_DCL_28*/"M";
                key = /*MSG0*/"paper";
            }
            : button {
                label = /*HPMPLOT_DCL_29*/"Advanced Media Opt...";
	        mnemonic = /*HPMPLOT_DCL_30*/"v";
                key = /*MSG0*/"advopt";
            }
        }  // End Right Column
    }  // End Row of two columns

    : boxed_column {
        : text {
            label = /*HPMPLOT_DCL_33*/"Current Annotation Comment:";
            key = /*MSG0*/"Annolabel";
        }
        : text {
            width = 50;
            key = /*MSG0*/"curcomment";
        }
    }

    : row {
        fixed_width = true;
        alignment = centered;
        : button {
            label = /*HPMPLOT_DCL_34*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_35*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_36*/"Save as...";
            key = /*MSG0*/"saveas";
	    mnemonic = /*HPMPLOT_DCL_37*/"S";
            width = 12;
        }
        : button {
            label = /*HPMPLOT_DCL_38*/"Help...";
            key = /*MSG0*/"helpmain";
            mnemonic = /*HPMPLOT_DCL_39*/"H";
            width = 12;
        }
    }
}  // End MAIN MENU Dialog //

//      PENATTR.DCL
//      Dialog Box for setting attributes for pens
//
penattr: dialog {
    label = /*HPMPLOT_DCL_40*/"Pens";
    initial_focus = /*MSG0*/"accept";
    fixed_height = true;
    : row {  // Pen
        : column {
            : popup_list {
                label = /*HPMPLOT_DCL_41*/"Pen (1..255):";
                mnemonic = /*HPMPLOT_DCL_42*/"P";
                fixed_width = true;
                key = /*MSG0*/"slider";
                edit_width = 4;
            }
            : button {
                label = /*HPMPLOT_DCL_43*/"Apply to All Pens";
                mnemonic = /*HPMPLOT_DCL_44*/"A";
                key = /*MSG0*/"okall";
            }
        }  // End Pen Column
        : column {
	    : boxed_row {
	        label = /*HPMPLOT_DCL_45*/"Plot Merge Control";
                : radio_column {  // Merge
                    key = /*MSG0*/"mc";
                    fixed_height = true;
                    : radio_button {
                        label = /*HPMPLOT_DCL_46*/"Lines Overwrite";
                        key = /*MSG0*/"mc0";
                        mnemonic = /*HPMPLOT_DCL_47*/"O";
                    }
                    : radio_button {
                        label = /*HPMPLOT_DCL_48*/"Lines Merge";
                        key = /*MSG0*/"mc1";
                        mnemonic = /*HPMPLOT_DCL_49*/"M";
                    }
                }  // End (Merge) column
	        : column {
	            fixed_width = true;
	            fixed_height = true;
	            :image {
		        key = /*MSG0*/"overw_im";
		        height = 1;
		        aspect_ratio = 1.4;
			color = black;
	            }
	            :image {
		        key = /*MSG0*/"merge_im";
		        height = 1;
		        aspect_ratio = 1.4;
			color = black;
	            }
                }
	        spacer_1;
            } //end merge row
	    : button {
	        label = /*HPMPLOT_DCL_50*/"Halftoning...";
	        key = /*MSG0*/"printop";
	        mnemonic = /*HPMPLOT_DCL_51*/"t";
	    }
        }
    }


    : row {
	:boxed_row {
            label = /*HPMPLOT_DCL_52*/"Line End:";
            key = /*MSG0*/"endlabel";
            mnemonic = /*HPMPLOT_DCL_53*/"E";
            : image_button {
                key = /*MSG0*/"end_tile1";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"end_tile2";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"end_tile3";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"end_tile4";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
        }
	:boxed_row {
            label = /*HPMPLOT_DCL_54*/"Line Join:";
            key = /*MSG0*/"joinlabel";
            mnemonic = /*HPMPLOT_DCL_55*/"J";
            : image_button {
                key = /*MSG0*/"join_tile1";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile2";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile3";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile4";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile5";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
        }
    }  // End Row (Line ends/joins)

    : row { // ( Ends, Joins, & patterns)
        : boxed_column {  // Fills
            label = /*HPMPLOT_DCL_56*/"Fill:";
            mnemonic = /*HPMPLOT_DCL_57*/"F";
            : list_box {
                fixed_height = true;
                height = 5;
                key = /*MSG0*/"filltype";
            }
            : edit_box {
                fixed_width = true;
                edit_width = 2;
	        edit_limit = 2;
                label = /*HPMPLOT_DCL_58*/"Spacing 1..99mm:";
                key   = /*MSG0*/"spacing";
                mnemonic = /*HPMPLOT_DCL_59*/"S";
            }

            : edit_box {
                fixed_width = true;
                edit_width = 3;
	        edit_limit = 3;
                label = /*HPMPLOT_DCL_60*/"Angle 0..359:";
                key   = /*MSG0*/"angle";
                mnemonic = /*HPMPLOT_DCL_61*/"g";
            }

            : edit_box {  // Shade
                fixed_width = true;
                edit_width = 2;
	        edit_limit = 2;
                label = /*HPMPLOT_DCL_62*/"Shade 0..99%:";
                key   = /*MSG0*/"shdpct";
                mnemonic = /*HPMPLOT_DCL_63*/"S";
            }  // End Shade
        }  // End column (Fills)

        : boxed_column { // Raster patterns, line ends line joins
            key = /*MSG0*/"rastpat";
            label = /*HPMPLOT_DCL_64*/"Raster Patterns:";
	    fixed_height = true;
            mnemonic = /*HPMPLOT_DCL_65*/"R";
            : list_box {
                fixed_height = true;
                height = 8;
	        key = /*MSG0*/"patlist";
            }
            : button {
                label = /*HPMPLOT_DCL_66*/"Change...";
                mnemonic = /*HPMPLOT_DCL_67*/"C";
                key = /*MSG0*/"changerast";
            }
        }  // End Column ( Raster Patterns )
    }  // End Row

    : row {
        fixed_width = true;
        alignment = centered;
        : retirement_button {
            label = /*HPMPLOT_DCL_68*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_69*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_70*/"Help...";
            key = /*MSG0*/"helppen";
            width = 12;
            mnemonic = /*HPMPLOT_DCL_71*/"H";
        }
    }

}  // End LINE ATTRIBUTES Dialog //

//      PENPPENATTR.DCL
//      Dialog Box for setting attributes for pens
//
penppenattr: dialog {
    label = /*HPMPLOT_DCL_40*/"Pens";
    initial_focus = /*MSG0*/"accept";
    fixed_height = true;
    : row {  // Pen
        : column {
            : popup_list {
                label = /*HPMPLOT_DCL_41*/"Pen (1..255):";
                mnemonic = /*HPMPLOT_DCL_42*/"P";
                fixed_width = true;
                key = /*MSG0*/"slider";
                edit_width = 4;
            }
            : button {
                label = /*HPMPLOT_DCL_43*/"Apply to All Pens";
                mnemonic = /*HPMPLOT_DCL_44*/"A";
                key = /*MSG0*/"okall";
            }
        }  // End Pen Column
        : column {
	    : boxed_row {
	        label = /*HPMPLOT_DCL_251*/"Generate Area Fills in:";
                : radio_column {  // SFILLS
                    key = /*MSG0*/"sfills";
                    fixed_height = true;
                    : radio_button {
                        label = /*HPMPLOT_DCL_252*/"Plotter (Best Lockout Time)";
                        key = /*MSG0*/"sfillspl";
                        mnemonic = /*HPMPLOT_DCL_253*/"l";
                    }
                    : radio_button {
                        label = /*HPMPLOT_DCL_254*/"AutoCAD (Best Plotting Time)";
                        key = /*MSG0*/"sfillsacad";
                        mnemonic = /*HPMPLOT_DCL_255*/"D";
                    }
                }  // End (Merge) column
            } //end merge row
        }
    }


    : row {
	:boxed_row {
            label = /*HPMPLOT_DCL_52*/"Line End:";
            key = /*MSG0*/"endlabel";
            mnemonic = /*HPMPLOT_DCL_53*/"E";
            : image_button {
                key = /*MSG0*/"end_tile1";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"end_tile2";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"end_tile3";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"end_tile4";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
        }
	:boxed_row {
            label = /*HPMPLOT_DCL_54*/"Line Join:";
            key = /*MSG0*/"joinlabel";
            mnemonic = /*HPMPLOT_DCL_55*/"J";
            : image_button {
                key = /*MSG0*/"join_tile1";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile2";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile3";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile4";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"join_tile5";
                width = 5;
                aspect_ratio = 0.75;
		color = black;
            }
        }
    }  // End Row (Line ends/joins)

    : row { // ( Ends, Joins, & patterns)
	key = /*MSG0*/"fillsdef";
        : boxed_column {  // Fills
            label = /*HPMPLOT_DCL_56*/"Fill:";
            mnemonic = /*HPMPLOT_DCL_57*/"F";
            : list_box {
                fixed_height = true;
                height = 5;
                key = /*MSG0*/"filltype";
            }
            : edit_box {
                fixed_width = true;
                edit_width = 2;
	        edit_limit = 2;
                label = /*HPMPLOT_DCL_58*/"Spacing 1..99mm:";
                key   = /*MSG0*/"spacing";
                mnemonic = /*HPMPLOT_DCL_59*/"S";
            }

            : edit_box {
                fixed_width = true;
                edit_width = 3;
	        edit_limit = 3;
                label = /*HPMPLOT_DCL_60*/"Angle 0..359:";
                key   = /*MSG0*/"angle";
                mnemonic = /*HPMPLOT_DCL_61*/"g";
            }

            : edit_box {  // Shade
                fixed_width = true;
                edit_width = 2;
	        edit_limit = 2;
                label = /*HPMPLOT_DCL_62*/"Shade 0..99%:";
                key   = /*MSG0*/"shdpct";
                mnemonic = /*HPMPLOT_DCL_63*/"S";
            }  // End Shade
        }  // End column (Fills)

        : boxed_column { // Raster patterns, line ends line joins
            key = /*MSG0*/"rastpat";
            label = /*HPMPLOT_DCL_64*/"Raster Patterns:";
	    fixed_height = true;
            mnemonic = /*HPMPLOT_DCL_65*/"R";
            : list_box {
                fixed_height = true;
                height = 8;
	        key = /*MSG0*/"patlist";
            }
            : button {
                label = /*HPMPLOT_DCL_66*/"Change...";
                mnemonic = /*HPMPLOT_DCL_67*/"C";
                key = /*MSG0*/"changerast";
            }
        }  // End Column ( Raster Patterns )
    }  // End Row

    : row {
        fixed_width = true;
        alignment = centered;
        : retirement_button {
            label = /*HPMPLOT_DCL_68*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_69*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_70*/"Help...";
            key = /*MSG0*/"helppen";
            width = 12;
            mnemonic = /*HPMPLOT_DCL_71*/"H";
        }
    }

}  // End LINE ATTRIBUTES Dialog //

//  ANNOTATE.DCL
//  Menu for annotating plot-time variables into left side of plot
//

annotate: dialog {
    label = /*HPMPLOT_DCL_72*/"Annotations";
    initial_focus = /*MSG0*/"accept";
    : row  { // of two columns
        : column {
            : toggle {
                label = /*HPMPLOT_DCL_73*/"Drawing Filename";
                key = /*MSG0*/"dwgname";
                mnemonic = /*HPMPLOT_DCL_74*/"F";
            }
            : toggle {
                label = /*HPMPLOT_DCL_75*/"Plot Date/Time";
                key = /*MSG0*/"plottime";
                mnemonic = /*HPMPLOT_DCL_76*/"T";
            }
        }  // End column (dwgname, plottime)
        : column {
            : toggle {
                label = /*HPMPLOT_DCL_77*/"Driver Info";
                key = /*MSG0*/"dvrname";
                mnemonic = /*HPMPLOT_DCL_78*/"I";
            }
            : toggle {
                label = /*HPMPLOT_DCL_79*/"Crop Marks";
                key = /*MSG0*/"cropmarks";
                mnemonic = /*HPMPLOT_DCL_80*/"M";
            }
        }  // End column ( drvname, cropmarks )
    }  // End row of 2 columns

    : column {
        : text {
            key = /*MSG0*/"commentlabel";
            label = /*HPMPLOT_DCL_81*/"Comments: (50 Characters Max)";
            mnemonic = /*HPMPLOT_DCL_82*/"C";
        }
        : edit_box {
            key = /*MSG0*/"comment";
            width = 51;
	    edit_limit = 50;
        }
    }  // End Comment column

    : row {
        fixed_width = true;
        alignment = centered;
        : retirement_button {
            label = /*HPMPLOT_DCL_83*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_84*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_85*/"Help...";
            key = /*MSG0*/"helpanno";
            mnemonic = /*HPMPLOT_DCL_86*/"H";
            width = 12;
        }
    }

}  // End PLOT ANNOTATE Dialog //


//  HELP DIALOG
//  The help dialog is popped up to display a help message based
//  on which "screen" the user was interacting with when he
//  depressed the help button

help: dialog {
    label = /*HPMPLOT_DCL_122*/"Help/Info";
    initial_focus = /*MSG0*/"accept";
    : list_box {
        width = 55;
        height = 16;
        key = /*MSG0*/"helplist";
    }
    : retirement_button {
        label = /*HPMPLOT_DCL_123*/"OK";
        key = /*MSG0*/"accept";
        is_default = true;
        is_cancel = true;
    }
}  // End HELP Dialog

//  OKALLPENS DIALOG
okallpens: dialog {
    fixed_width = true;
    alignment = centered;
    label = /*HPMPLOT_DCL_124*/"!! CAUTION !!";
    initial_focus = /*MSG0*/"accept";
    : text {
        label = /*HPMPLOT_DCL_125*/"OK to apply settings to ALL pens?";
        key = /*MSG0*/"askok";
    }
    : row {
        alignment = centered;
        : retirement_button {
            label = /*HPMPLOT_DCL_126*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_127*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
    }  // End row
}  // End OKALLPENS Dialog //

paperor : dialog {
    label = /*HPMPLOT_DCL_128*/"Media Options";
    initial_focus = /*MSG0*/"accept";
    : boxed_row {
        label = /*HPMPLOT_DCL_129*/"Click on Match for Your Image and Media";
        fixed_width = true;
        fixed_height = true;
        spacer_0;
        : column {
            fixed_width = true;
            fixed_height = true;
            : image_button {
                key = /*MSG0*/"image1";
                width = 14;
                aspect_ratio = 0.65;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"image3";
                width = 14;
                aspect_ratio =0.65;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"image5";
                width = 14;
                aspect_ratio =0.65;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"image7";
                width = 14;
                aspect_ratio = 0.65;
		color = black;
            }
        }
        spacer_0;
        : column {
            fixed_width = true;
            fixed_height = true;
            : image_button {
                key = /*MSG0*/"image2";
                width = 14;
                aspect_ratio = 0.65;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"image4";
                width = 14;
                aspect_ratio = 0.65;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"image6";
                width = 14;
                aspect_ratio = 0.65;
		color = black;
            }
            : image_button {
                key = /*MSG0*/"image8";
                width = 14;
                aspect_ratio = 0.65;
		color = black;
            }
        }
        spacer_0;
    }
    : row {
        fixed_width = true;
        alignment = centered;
        : retirement_button {   
            label = /*HPMPLOT_DCL_130*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_131*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_132*/"Help...";
            mnemonic = /*HPMPLOT_DCL_133*/"H";
            key = /*MSG0*/"helppaper";
        }
    }  // End Row;
}


paperadv : dialog {
    label = /*HPMPLOT_DCL_134*/"Advanced Media Options";
    initial_focus = /*MSG0*/"accept";
    : boxed_row {
        label = /*HPMPLOT_DCL_135*/"Select level of control for plotter margins";
        : boxed_radio_column {
            label = /*HPMPLOT_DCL_136*/"If Scaled to Fit is OFF";
	    key = /*MSG0*/"sclmarginadj";
            : radio_button {
                label = /*HPMPLOT_DCL_137*/"Display clip warnings";
                key = /*MSG0*/"sclwarnings";
		mnemonic = /*HPMPLOT_DCL_138*/"w";
            }
            : radio_button {
                label = /*HPMPLOT_DCL_139*/"Don't display warnings";
                key = /*MSG0*/"scldisabled";
		mnemonic = /*HPMPLOT_DCL_140*/"D";
            }
        }
	: boxed_radio_column {
            label = /*HPMPLOT_DCL_141*/"If Scaled to Fit is ON";
	    key = /*MSG0*/"marginadj";
            : radio_button {
                label = /*HPMPLOT_DCL_142*/"Don't clip. Adjust to media";
                key = /*MSG0*/"adjust";
		mnemonic = /*HPMPLOT_DCL_143*/"A";
            }
            : radio_button {
                label = /*HPMPLOT_DCL_144*/"Display clip warnings";
                key = /*MSG0*/"warnings";
		mnemonic = /*HPMPLOT_DCL_145*/"w";
            }
            : radio_button {
                label = /*HPMPLOT_DCL_146*/"Don't display warnings";
                key = /*MSG0*/"disabled";
		mnemonic = /*HPMPLOT_DCL_147*/"D";
            }
        }
    }
    : boxed_column {
        label = /*HPMPLOT_DCL_148*/"Plotter Margins";
        : radio_row {
  	    key = /*MSG0*/"expand";
            : radio_button {
                label = /*HPMPLOT_DCL_149*/"Expand OFF";
                key = /*MSG0*/"expoff";
	        mnemonic = /*HPMPLOT_DCL_150*/"F";
            }
            : radio_button {
                label = /*HPMPLOT_DCL_151*/"Expand ON";
                key = /*MSG0*/"expon";
	        mnemonic = /*HPMPLOT_DCL_152*/"N";
            }
	}
	: text {
	    label = /*HPMPLOT_DCL_153*/"Must correspond to plotter setting";
	}
    }
    : row {
        fixed_width = true;
        alignment = centered;
        : retirement_button {   
            label = /*HPMPLOT_DCL_154*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_155*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_156*/"Help...";
            mnemonic = /*HPMPLOT_DCL_157*/"H";
            key = /*MSG0*/"helpadv";
        }
    }  // End Row;
    : text {
	key = /*MSG0*/"errortext";
	width = 55;
    }
}


printops : dialog {
    label = /*HPMPLOT_DCL_238*/"Halftoning";
    initial_focus = /*MSG0*/"accept";
    : text {
        centered = true;
        label = /*HPMPLOT_DCL_239*/"(Only for vectors)";
    }
    : row {
        : radio_column {
	    key = /*MSG0*/"dither";
	    : radio_button {
		label = /*HPMPLOT_DCL_240*/"Scatter";
		key = /*MSG0*/"scatter";
		mnemonic = /*HPMPLOT_DCL_241*/"S";
	    }
	    : radio_button {
		label = /*HPMPLOT_DCL_242*/"Pattern";
		key = /*MSG0*/"pattern";
		mnemonic = /*HPMPLOT_DCL_243*/"P";
	    }
	    : radio_button {
		label = /*HPMPLOT_DCL_244*/"Plotter default";
		key = /*MSG0*/"default";
		mnemonic = /*HPMPLOT_DCL_245*/"d";
	    }
        }
        : column {
	    fixed_width = true;
	    fixed_height = true;
	    : image {
		key = /*MSG0*/"sc_im";
		height = 1;
		aspect_ratio = 6;
		color = black;
	    }
	    : image {
		key = /*MSG0*/"pt_im";
		height = 1;
		aspect_ratio = 6;
		color = black;
	    }
	    spacer_1;
        }
    }
    : row {
        fixed_width = true;
        alignment = centered;
        : retirement_button {   
            label = /*HPMPLOT_DCL_246*/"OK";
            key = /*MSG0*/"accept";
            width = 12;
            is_default = true;
        }
        : retirement_button {
            label = /*HPMPLOT_DCL_247*/"Cancel";
            key = /*MSG0*/"cancel";
            width = 12;
            is_cancel = true;
        }
        : button {
            label = /*HPMPLOT_DCL_248*/"Help...";
            mnemonic = /*HPMPLOT_DCL_249*/"H";
            key = /*MSG0*/"helpprintop";
        }
    }  // End Row;
}

