// Next available MSG number is    25 
// MODULE_ID DDCHPROP_DCL_
/* Next available MSG number is  23 */

//     DDCHPROP.DCL        Version 1.0
//
//     Copyright (C) 1991, 1992, 1993, 1994 by Autodesk, Inc.
//
//     Permission to use, copy, modify, and distribute this software
//     for any purpose and without fee is hereby granted, provided
//     that the above copyright notice appears in all copies and
//     that both that copyright notice and the limited warranty and
//     restricted rights notice below appear in all supporting
//     documentation.
//
//     AUTODESK PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
//     AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
//     MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK, INC.
//     DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
//     UNINTERRUPTED OR ERROR FREE.
//
//     Use, duplication, or disclosure by the U.S. Government is subject to
//     restrictions set forth in FAR 52.227-19 (Commercial Computer
//     Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii)
//     (Rights in Technical Data and Computer Software), as applicable.
//
//.
//
//    Dialogue for the DDCHPROP command, for use with DDCHPROP.LSP
//


//dcl_settings : default_dcl_settings { audit_level = 3; }


textbox : edit_box {
    vertical_margin = tiny;
    horizontal_margin = tiny;
}

ch_prop : dialog {
    label = "Change Properties";
    : row {
        : column {
            fixed_width = true;
            : row {
                : button {
                    label = "Color...";
                    mnemonic = "C";
                    key = "b_color";
                    width = 14;
                    fixed_width = true;
                }
                : image_button {
                    key = "show_image";
                    height = 1;
                    width = 3;
                }
                : text {
                    key = "t_color";
                    width = 31;
                }
            }
            : row {
                : button {
                    label = "Layer...";
                    mnemonic = "L";
                    key = "b_name";
                    width = 14;
                    fixed_width = true;
                }
                : spacer { width = 3; }
                : text {
                    key = "t_layer";
                    width = 31;
                }
            }
            : row {
                : button {
                    label = "Linetype...";
                    mnemonic = "i";
                    key = "b_line";
                    width = 14;
                    fixed_width = true;
                }
                : spacer { width = 3; }
                : text {
                    key = "t_ltype";
                    width = 31;
                }
            }
        }
    }
    spacer;
    : row {
       alignment = left;
       : text_part {
           label = "Linetype Scale:";
	       mnemonic = "S";
	       width = 16;
	       fixed_width = true;
	   }
       : edit_box {
	       key = "eb_ltscale";
           edit_width = 18;
           fixed_width = true;
           width = 35;
       }
    }
    : row {
       alignment = left;
       : text_part {
           label = "Thickness:";
           mnemonic = "T";
	       width = 16;
	       fixed_width = true;
       }
       : edit_box {
           key = "eb_thickness";
           edit_width = 18;
           fixed_width = true;
           width = 35;
       }
    }
    spacer;
    ok_cancel_help_errtile;
}

setcolor : dialog {
    label = "Select Color";
    image_block;
    : list_box {
        key = "list_col";
        allow_accept = true;
    }
    : textbox {
        key = "edit_col";
        allow_accept = false;
        label = "Color Code:";
        edit_width = 13;
     }
     ok_cancel_err;
}

setltype : dialog {
    label = "Select Linetype";
    image_block;
    : list_box {
        key = "list_lt";
        allow_accept = true;
    }
    : edit_box {
        key = "edit_lt";
        allow_accept = false;
        label = "Linetype:";
        mnemonic = "L";
	edit_limit = 217;
    }
    ok_cancel;
    errtile;
}

setlayer : dialog {
    subassembly = 0;
    label = "Select Layer";
    initial_focus = "listbox";
    : concatenation {
        children_fixed_width = true;
        key = "clayer";
        : text_part {
            label = "Current Layer: ";
        }
        : text_part {
            key = "cur_layer";
            width = 35;
        }
    }
    : row {
        fixed_width = true;
        key = "titles";
        children_fixed_width = true;
        : text {
            label = "Layer Name";
            width = 34;
        }
        : text {
            label = "State";
            width = 9;
        }
        : text {
            label = "Color";
            width = 8;
        }
        : text {
            label = "Linetype";
        }
    }
    : list_box {
        width = 67;
        tabs = "32 35 37 39 41 44 53";
        height = 12;
        key = "list_lay";
        allow_accept = true;
    }
    : row {
        key = "controls";
        : column {
            key = "lname";
            fixed_width = true;
            : edit_box {
                label = "Set Layer Name:";
                mnemonic = "S";
                key = "edit_lay";
                edit_width = 32;
                edit_limit = 217;
                allow_accept = true;
            }
        }
    }
    ok_cancel_err;
}


